PICアセンブラーで芸当（?）その4）もっと接続－余裕の8ピン！
前回の回路に別のI2C接続センサーを加えても余裕で処理できるでしょう。それだと面白くないので、試しに別の1ワイヤー・プロトコル（1-wire protocol）の温湿度センサーを加え、温湿度計付時計に拡張してみます。
ディスプレイの表示を2秒ごとに時刻、温度、湿度と順次切り替えて動きます。次の動画のように時刻設定もできます。実は思わぬ問題が出て解決したのですが、それは後ろのほうに書きます。改良したソースプログラム全体を最後につけておきます。
「手が空いたときには前のプログラムの解説を」と考えていましたが、この3連休の真ん中で拡張を思いつきました。こちらのほうが面白く役立つかも。(なお、これとは別に、少しずつ作っている新案のオリジナル・レーザーエングレーバーが進んでいますが、このブログの別記事に後で記載するとします。）
この記事では2ピンのI2Cプロトコル、2ピンのTM16xxプロトコル、1ピンの1ワイヤプロトコルの3種を、たった3ピンで動かしています。加えてタクトスイッチ3つの計6ピン。PIC12F1822の容量は、プログラム、データともに6割以上の余裕があります。これこそアセンブラー以外ではできない芸と、勝手に楽しんでいます^^； そもそも8ピンPICは小さくてDIP実装ですむので扱いやすいですからね。
プログラムは他のPICに簡単に乗せ換えられるようにコーディングしています。ポートとピンのEqu、始まりのDevsetマクロのピン設定を変えるだけで動きます。例えば14ピンPIC16F1825は12F1822からの上位互換性があり、データメモリーは8倍の1024バイト、プログラムメモリーは4倍の8Kワード。この場合そんなに要りませんが。
さて、ここでの温湿度センサーは、安価なDHT11のブレークアウト・モジュールです。
かなり前に1個数十円で沢山買った部品です。 作りもいかにも安っぽく、グリルがまがって付いていたりして。。とはいえ、測定温度も湿度も妥当な値を示し、熱容量も小さくて敏感です。小数点以下も表示する同シリーズのDHT22とインターフェイスもデータ構成も同じです（DHT11では小数点以下のデータにゼロが埋められているだけです）。
このデバイスは標準の1ワイヤープロトコルからID（アドレス）が省かれた、シンプルなものです。1ワイヤー接続は便利で簡単ですが、グランドとのツイストペアで通信距離が長くとれます。非同期通信とは違い、エラーが起こりにくい通信方式でよく考えられたものだと感心します。原理はモールス符号のようなものです。
長短のH信号をその長さの差で検出すればよいので、処理は簡単です。各符号1ビットの終わりから計時を再開すれば常に同期が保たれ、非同期のように狂ってきません。簡単さは最後につけたプログラムをご参照下さい。
次の測定は、このプログラムでの長短符号（Channel-1)と、その検出タイミング（Channel-4)を示します。
当プログラムでは、測定用信号はタクトスイッチTime用入力ピンを共有して出力できるようにしてあります。プログラム中の1か所にあるTriggerマクロ命令使用箇所のコメント（；）をはずせばそのまま動きます。（そのままコメントを外しておいても支障はありません。時刻設定モードでこれをタクトスイッチとして使いますが、そのモードではDHT11との通信はしないからです。）
1ワイヤー・デバイスの信号は、検出タイミングでHなら1、Lなら0という単純な形式でできていて、最後にエラーチェック符号が送られます。こういう表示用途の場合は、テスト時以外はそのチェックは不要でしょうし、実際にエラーは起きません。通信距離が長いような時はチェックが要るかもしれませんね。
1ワイヤー・インターフェイスはI2C接続と同様にプルアップされ（デバイスの写真に4.7KΩ＝472が写っていますね）、オープンコレクタ（オープンドレーン）での接続を前提にしています。ですので、デジタル入出力ピンで直接接続する際は以前の記事に書いたように、100Ω程の抵抗を介した方が安全。ただし、1ワイヤーでの反対極での引き合いは通信スタート時に短時間生じるだけなので、なしでよいかもしれません。この例では後のほうでご紹介しますが、別の理由でCRをつけました。
さて、回路は最初は次のものでテストしていました。
順調に動いていましたが、時刻設定をする際にTM1637の表示が点滅したりするのに気づきました。何が起きているかを調べたら、クロック信号数百回に1度ぐらい、DHT11が反応しているではありませんか！これには本当にびっくり。
そのためTM1637へ向けたクロック信号はすっかり邪魔をされています。上の測定でチャネル3はTM1637のDIOです。その形を詳しく分析すると、TM1637向け信号がたまに輝度変更コマンドに化けたりしています。他のコマンドにも化けるでしょう。
そもそも、1ワイヤではクロック線のLが18ｍS以上続いて次に一定時間Hにならないとデバイス（DHT11）は反応しないことになっています。よって共用で問題なしと確信していたのですが、何が起こっているのでしょうか？ここではクロックはI2C用にもTM1637用にも大体100KHｚにしてあり、長く継続してLowということは絶対ありません。
しかし、それに反応したDHT11からの信号は、ホストのクロック送信を上書きする程強力（低インピーダンス）です。そのため、上の測定例ではTM1637向けのクロック信号を、遅いその信号が上書きしています！
そこで考え込んでしまいました。
もともと長いLowで信号開始の合図とする理由は、アナログ時代にデバイスがプルアップ電圧を抜く時間として設定された経緯からです。ところが、現代のセンサー機器は悉くデジタル処理で、電圧はサンプリングしてみている筈です。
DHT11が18ｍS以上継続してLowと認識したということは、一定間隔でサンプリングした結果運悪く全てがLowの点だけとなり、さらにH検出でもHだけになったということで、それがたまに起きているに相違ないでしょう。クロック信号自体が一定周期で繰り返されますし、10倍ほどゆっくりのDHT11のサンプリング間隔は長い筈ですから。それでDHT11側で「空耳」がおきているわけです！
もしそれが原因ならば対策は簡単！信号約10KHzの1ワイヤDHT11には必要のない100KHzブロック波を聞こえなくします。つまりDHT11へ向かう信号線に簡単なRCローパスフィルタを入れればよいわけです。時定数RxC＝2μSを入れたら、DHT11側では100KHzブロック波は十分になまり、全く識別しなくなりました。DHT11が必要とする遅い信号には全く影響しない点もオシロで確認しました。
それが次の最終回路図です。
そして、ブレッドボードは最終的に次のようになりました。右上のほうにRとCを入れただけですが。
これで完全なものになったと思いますので、次にソースプログラムをつけておきます。
I2C用とTM16xx用の各2線プロトコル、それにDHTxx用の1線プロトコルの3つが共存しています。それでもアプリケーションを含めてプログラムメモリーは815ワード（2048ワード中の39.8％）、データメモリーは39バイト（128バイト中の30.5％）しか使っていません。もっと色々できますね。
;U190915-RTC-DHT11-TM16-V01s.asm As of Sept. 15, 2019
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; ;
; RTC Reader/Writer, DHT11 reader & TM1637 display with PIC12F1822 V01 ;
; (C)2015-2019 Akira Tominaga, All rights reserved. ;
; Major revisions ;
; V00 Original version Sept.8, 2019 ;
; V01 Raise 2-wire speed (both I2C and TM16xx) to 100kHz ;
; ;
; Function ;
; 1.Show time, temperature, & humidity on TM1637 4 digit display ;
; 2.Update DS3231 calendar and time when Set switch pushed ;
; Mode switch to change calendar/time unit ;
; Time switch to change value of the unit within its range ;
; ;
; Input/output ;
; RA0 Set switch (swSet) input pulled-up ;
; RA1 Time switch (swTime) input pulled-up ;
; Used as LED or DSO trigger when debugging ;
; RA2 DIO for TM1637 outuput usually and input occasionally ;
; RA3 Mode switch (swMode) input pulled-up ;
; RA4 SDA for I2C-RTC output usually and input occasionally ;
; RA5 SCL for I2C-RTC output, CLK for TM1637 output, and ;
; DHT11 1-wire output/input with Low-pass filter 200ohm+0.01μF;
; ;
; Remarks ;
; 1. Clock = HFINTOSC ( 16MHz) ;
; Hence 1 step = 0.25 micro seconds ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
list p=12F1822 ; list directive to define processor
#include ; ＜p12F1822.inc＞ specific variables
__CONFIG _CONFIG1, _FOSC_INTOSC & _WDTE_OFF & _PWRTE_OFF & _MCLRE_OFF & _CP_OFF & _CPD_OFF & _BOREN_OFF & _CLKOUTEN_OFF & _IESO_OFF & _FCMEN_OFF
__CONFIG _CONFIG2, _WRT_OFF & _PLLEN_OFF & _STVREN_OFF & _BORV_LO & _LVP_OFF
; page
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Macro definitions ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Device dependent Macros ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
DEVset macro
BANKSEL OSCCON ; Bank=1
movlw B'01111010' ; 16MHz and internal oscillator
movwf OSCCON
;
; BANKSEL INTCON ; Interrupt Con (in all banks hence comment)
clrf INTCON ; Disable all interrupts
;
; PORTA initialization
BANKSEL PORTA ; Bank=0
clrf PORTA
; BANKSEL LATA ; Bank=2
; clrf LATA
BANKSEL ANSELA ; Bank=3
clrf ANSELA ; No use of ADC
BANKSEL ADCON0 ; Bank=1
clrf ADCON0 ; No use of ADC
;
BANKSEL TRISA ; Bank=1
movlw B'11001011' ; RA2,4 and 5 are output
movwf TRISA
;
BANKSEL OPTION_REG ; Bank=1
bcf OPTION_REG,7 ; Enable weak pull-up
BANKSEL WPUA ; Bank=4
movlw B'00001011' ; Weak Pull-up for RA 0,1,and 3
movwf WPUA ;
;
clrf BSR ; Bank=0
InitP ; Initialize ports
endm
;
InitP macro ; Initialize ports
movlw B'11111111' ; All inputs pulled-up and outputs H
movwf PORTA
endm
;
; for I2C-Master protocol
; Sending data to I2C slave
I2Csnd macro slave,dataa,datalen
movlw slave
movwf I2Cadr
movlw dataa
movwf FSR0L
movlw datalen
movwf DataLen
call I2Csndr
endm
;
; Receiving data from I2C slave
I2Crcv macro slave,dataa,datalen
movlw slave
movwf I2Cadr
movlw dataa
movwf FSR0L
movlw datalen
movwf DataLen
call I2Crcvr
endm
;
; I2C start signal
I2Cstat macro
call I2Cstar
endm
;
; I2C stop signal
I2Cstop macro
call I2Cstpr
endm
;
; For TM16xx-Master protocol
; Sending Literal to TM16xx
TMsendL macro tslit ; Send a literal to TM1637
movlw tslit
call TMsndLr
endm
;
; Sending a Byte to TM16xx
TMsendB macro tsbyte ; Send a Byte specified, to TM1637
movf tsbyte,W
movwf Sbyte
call TMsndBr
endm
;
; TM16xx start signal
TMstart macro ; Start TM16xx lines
call TMstrtr
endm
;
; TM16xx stop signal
TMstop macro ; Stop TM16xx lines
call TMstopr
endm
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; API and I/O macros ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;for TM1637 application interfaces
;display 4 literal characters directly to TM1637
dsp4chr macro d1000,d100,d10,d1
movlw d1000
movwf Dig1000
movlw d100
movwf Dig100
movlw d10
movwf Dig10
movlw d1
movwf Dig1
call TMdspr
endm
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Time cosuming macros ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Mic macro ;Consume 1 μS only
goto $+1
goto $+1
endm
;
Mic2 macro mic2p ;Consume 2 μS x n
movlw mic2p
call Mic2r
endm
;
Mic2p5 macro mic25p ; Consume 2.5μS x n
movlw mic25p
call Mic25r
endm
;
Mic5 macro mic5p ; Consume 5μS x n
movlw mic5p
call Mic25r
movlw mic5p
call Mic25r
endm
;
Mic50 macro mic50p ; Consume 50μS x n
movlw mic50p
call Mic50r
endm
;
Milli macro millip ; Consume mS x n
movlw millip
call Millir
endm
;
Mil100 macro mil100p ; Consume 100 mS x n
movlw mil100p
call Mil100r
endm
;
Secs macro secsp ; Consume Second x n
movlw secsp
call Secsr
endm
;
Mins macro minsp ; Consume Minute x n
movlw minsp
call Minsr
endm
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Debug and Abend macros ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
LEDon macro ; LED on macro for debugging
bcf Flags,LEDpH ; Clear LEDpin flags beforehand,
bcf Flags,LEDpIn ; as timing before PORT accessed
btfsc PORTdbg,LED ; Has LED been H before debug?
bsf Flags,LEDpH ; Yes, set LEDpH flag
BANKSEL TRISdbg ; Select TRIS bank
btfss TRISdbg,LED ; Has LED pin been input?
goto $+4 ; No, skip the next 3 steps
clrf BSR ; Point Bank0
bsf Flags,LEDpIn ; Show LED pin was input
BANKSEL TRISdbg ; Select Tris bank again
;
bcf TRISdbg,LED ; Set LED output mode, in any case
clrf BSR ; Point Bank 0
bsf PORTdbg,LED ; LED on
goto $+1 ; Timing after PORTdbg changed
endm
;
LEDoff macro ; LED off macro for debugging
goto $+1 ; Avoid PORT-update timing problem
bcf PORTdbg,LED ; LED off
btfss Flags,LEDpIn ; Was LEDpin input before debug?
goto $+7 ; No, skip the following 6 steps
;
BANKSEL TRISdbg ; Select TRISdbg bank
bsf TRISdbg,LED ; Set LED pin input again
BANKSEL WPUdbg ; Select WPUdbg, assuming Pulled-up
bsf WPUdbg,LED ; Weak Pull-up for input pin
clrf BSR ; Point Bank 0
goto $+3 ; skip the next 2 steps
;
btfsc Flags,LEDpH ; Was LEDpin High
bsf PORTdbg,LED ; Yes, set LED pin High
bcf Flags,LEDpH ; Clear LED flags,
bcf Flags,LEDpIn ; as timing after PORTdbg changed
endm
;
Trigger macro ; Trigger for DSO
bcf Flags,TrigpH ; ClearTrigger flags beforehand
bcf Flags,TrigpIn ; for timing before PORT changed
btfsc PORTdbg,Trig ; Has Trig pin been H before debug?
bsf Flags,TrigpH ; Yes, set TigpH flag
BANKSEL TRISdbg ; Select TRIS bank
btfss TRISdbg,Trig ; Has Trig pin been input?
goto $+4 ; No, skip the following 3 steps
clrf BSR ; Yes, point Bank 0,
bsf Flags,TrigpIn ; and show Trig pin was input,
BANKSEL TRISdbg ; select TRISdbg bank again
;
bcf TRISdbg,Trig ; Set Trig pin output, in any case
clrf BSR ; Point Bank 0
btfss Flags,TrigpH ; Was Trigger pin H?
goto $+3 ; No, goto slope-rising trigger
bcf PORTdbg,Trig ; Yes, set slope-falling trigger
goto $+2 ; and skip next line
bsf PORTdbg,Trig ; Slope-rising trigger
;
Mic2 2 ; Trigger for 4 micro seconds
movlw TrigpV ; Set trigger pin value to W
xorwf PORTdbg,F ; Stop trigger (H/L to L/H)
;
btfss Flags,TrigpIn ; Was Trig pin input before debug?
goto $+10 ; No, skip the following 9 steps
;
BANKSEL TRISdbg ; Select TRISdbg bank
bsf TRISdbg,Trig ; Set Trig-pin input
clrf BSR ; Select Bank 0
btfsc Flags,TrigpH ; Was Trigger pin L?
goto $+4 ; Yes, skip the followings
BANKSEL WPUdbg ; No,Bank select for WPUdbg
bsf WPUdbg,Trig ; Weak Pull-up for input pin
clrf BSR ; Re-select Bank 0
goto $+7 ; skip next 6 steps for output
;
btfss Flags,TrigpH ; Was Trigger pin H?
goto $+3 ; No, skip next 2 steps
bsf PORTdbg,Trig ; Yes, Set trig pin H
goto $+2 ; and skip next line
bcf PORTdbg,Trig ; Set trig pin L
;
bcf Flags,TrigpH ; Clear flags for trigger
bcf Flags,TrigpIn ; as timing after PORTdbg changed
endm
;
Udebug macro Addr
movf Addr,W
call Udbgr
endm
;
Uabend macro abn ; User Abnormal-end number
movlw abn
goto Uabendr
endm
;
Ublink macro bno ; Blink LED for specified times
movlw bno
call Ublinkr
endm
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Logic macros ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Comparison macros ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Compare A w/ B and branch to Smaller, Equal, or Larger(next statm't line)
CabSEL macro Aadr,Badr,Smladr,Eqladr
movf Badr,W ; W=B
subwf Aadr,W ; W=A-B
btfss STATUS,C ; A≧B? Yes, skip next
goto Smladr ; If A＜B goto Smaladr
btfsc STATUS,Z ; A＝B? No skip next
goto Eqladr ; If A＝B goto Eqladr
; ; If A＞B then next (here)
endm
;
; Compare A w/ B and branch to Smaller or Others (Equal or Larger)
CabSO macro Aadr,Badr,Smladr
movf Badr,W ; W=B
subwf Aadr,W ; W=A-B
btfss STATUS,C ; A≧B? Yes, skip next
goto Smladr ; If A＜B goto Smaladr
; ; If A≧B then next (here)
endm
;
; Compare A w/ B and branch to Equal, or Other(next statm't line)
CabEO macro Aadr,Badr,Eqladr
movf Badr,W ; W=B
subwf Aadr,W ; W=A-B
btfsc STATUS,Z ; A=B?
goto Eqladr ; If A=B goto Eqljmp
; ; else next (here)
endm
;
; Compare A w/ literal and branch to Smaller, Equal, or Larger(next statm't)
CalSEL macro Aadr,Blit,Smladr,Eqladr
movlw Blit ; W=B
subwf Aadr,W ; W=A-B
btfss STATUS,C ; A≧B? Yes, skip next
goto Smladr ; If A＜B goto Smaladr
btfsc STATUS,Z ; A=B? No skip next
goto Eqladr ; If A＝B goto Eqladr
; ; If A＞B then next (here)
endm
;
; Compare A w/ literal and branch to Smaller, or Others (Equal or Larger)
CalSO macro Aadr,Blit,Smladr
movlw Blit ; W=B
subwf Aadr,W ; W=A-B
btfss STATUS,C ; A≧B? Yes, skip next
goto Smladr ; If A＜B goto Smaladr
; ; If A≧B then next (here)
endm
;
; Compare A w/ literal and branch to Equal, or Others
CalEO macro Aadr,Blit,Eqladr
movlw Blit ; W=B
subwf Aadr,W ; W=A-B
btfsc STATUS,Z ; A=B? No skip next
goto Eqladr ; If A=B goto Eqladr
; ; else next (here)
endm
;
; Compare A w/ literal and branch to Large, or Others
CalLO macro Aadr,Blit,Ladr
movlw Blit ; W=B
subwf Aadr,W ; W=A-B
btfss STATUS,C ; A≧B? Yes, skip next
goto $+3 ; If A＜B goto Others
btfss STATUS,Z ; A=B? Yes skip next
goto Ladr ; If A＞B goto Laddr
; ; If A≦B then next (here)
endm
;
; Compare A with Literal and branch to Un-equal, or Others
CalUO macro Aadr,Blit,Uneqladr
movlw Blit ; W=B literal
subwf Aadr,W ; W=A-B
btfss STATUS,Z ; A=B?
goto Uneqladr ; No, goto unequal
; ; If yes then next
endm
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Files and Equations ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Files ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
cblock H'20'
;
; For Application support
ModeN ; Mode to point BCD mem addr of RTC
T7Chr ; 7 segment character to show ModeN
RvMax ; Max number of RTC data in ModeN
RvMin ; Minimum num of RTC data in ModeN
Byteh ; Work area as high byte of a word
Bytel ; Work area as low byte of a word
Sbyte ; Byte to be sent/received by devices
Bytectr ; Byte counter for device processes
Bitctr ; Bit counter for device processes
;
; For RTC
RTCmem ; RTC memory address
BCDsec ; RTC memory 0 = Second BCD 00-59
BCDmin ; RTC memory 1 = Min BCD 00-59
BCDhr ; RTC memory 2 = Hour BCD 00-23
BCDdow ; RTC memory 3 = Day of Week 01-07
BCDday ; RTC memory 4 = Day BCD 01-31
BCDmon ; RTC memory 5 = Month BCD 01-12
BCDyr ; RTC memory 6 = Year yy BCD 00-99
;
; For I2C protocols
I2Cadr ; Destinated slave I2C address
DataLen ; Number of bytes to be sent/received
;
; For TM1637 4 digit display
; Sbyte ; Byte to send, shared with I2C
Dig1000 ; Digit 1000
Dig100 ; Digit 100
Dig10 ; Digit 10
Dig1 ; Digit 1
;
; For DHT11 input data area
DHTrh ; Relative humidity integer
DHTrhd ; Relative humidity digit under 1
DHTt ; Temperature integer
DHTtd ; Temperature digit under 1
DHTcks ; Checksum
;
; Areas for time consuming subroutines
Mic25c
Mic50c
Millic
Mil100c
Secsc
Minsc
;
; Areas for debugging routines
DmpA ; Display byte area
Dmp8C ; Bit counter for loop (Initial Dmp8V =8)
BlinkC ; Counter for blinking (set for Debugb or Abendb)
Abendn ; Abend number
Ucpc ; User Check point chr to trace
Flags ; Flags mainly for debug
;
endc
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Equations ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; For PORTA ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;swSet equ 0 ; PORTsw Set switch
;swTime equ 1 ; PORTsw Time switch
;LED equ 1 ; PORTdbg LED for debugging
;Trig equ 1 ; PORTdbg Trig for debugging
;Dio equ 2 ; PORTtm TM16xx DIO
;swMode equ 3 ; PORTsw Mode Switch
;Dl equ 4 ; PORTI2C SDA
;Cl equ 5 ; PORTI2C SCL
;Clk equ 5 ; PORTtm TM16xx CLK
;DHT11 equ 5 ; PORTdht DHT11 one wire signal
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; *** Logical PORTI2C ; Change this when port changed
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
PORTI2C equ PORTA ;
Dl equ 4 ; I2C Data line = SDA
Cl equ 5 ; I2C Clock line = SCL
LATI2C equ LATA ; LATch for I2C port
TRISI2C equ TRISA ; TRIS reg for I2C
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; *** Logical PORTtm ; Change this when port changed
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
PORTtm equ PORTA ;
Dio equ 2 ; TM16xx Data line = DIO
Clk equ 5 ; TM16xx Clock line = CLK
LATtm equ LATA ; Latch for tm port
TRIStm equ TRISA ; TRIS for tm
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; *** Logical PORTdht ; Change this when port changed
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
PORTdht equ PORTA ;
DHT11 equ 5 ; DHT11 one-wire signal
LATdht equ LATA ; Latch for dht port
TRISdht equ TRISA ; TRIS for dht
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; *** Logical PORTsw ; Change this when port changed
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
PORTsw equ PORTA
swSet equ 0 ; Set switch input pulled-up
swTime equ 1 ; Time switch input pulled-up
swMode equ 3 ; Mode switch input ulled-up
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; *** Logical PORTdbg ; Change this when port changed
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
PORTdbg equ PORTA
TRISdbg equ TRISA
WPUdbg equ WPUA
LED equ 1 ; LED when debugging
Trig equ 1 ; Trigger for DSO when debugging
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Values & Characters ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Equations for RTC DS3231
Clkt equ 1 ; Clock-time/4 multiplier of 2.5μS
Clkq equ 1 ; Quick time within clock 2μS
DS3231 equ H'D0' ; RTC DS3231 address (to write)
RTCdata equ BCDsec ; RTC memory data top
ModeMax equ 6 ; RTC data pointer ModeN max
ModeMin equ 0 ; RTC data pointer ModeN minimum
;
secMax equ H'59'
secMin equ 0
;
minMax equ H'59'
minMin equ 0
;
hrMax equ H'23'
hrMin equ 0
;
dowMax equ H'07'
dowMin equ H'01'
;
dayMax equ H'31'
dayMin equ H'01'
;
monMax equ H'12'
monMin equ H'01'
;
Modeyr equ 6
yrMax equ H'99'
yrMin equ 0
;
; 7 segment LED characters for TM1637
Ch7Y equ H'6E'
Ch7Eq equ H'48'
Ch7M equ H'37'
Ch7d equ H'5E'
Ch7w equ H'1C'
Ch7h equ H'74'
Ch7m equ H'54'
Ch7S equ H'6D'
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; For Debug ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
PORTdbg equ PORTA ;
Trig equ 1 ; DSO trigger pulse port for test use
TrigpV equ B'00000010' ; = 2^Trig
;
Dmp8V equ D'8' ; Debug display bit counter initial value
Debugb equ D'8' ; number of blinkings to show Debugging
Abendb equ D'25' ; number of blinkings to notify Abend
; Flags byte
LEDpH equ 0 ; LED pin was High before debug use
LEDpIn equ 1 ; LED pin was input before debug use
TrigpIn equ 2 ; Trigger pin was input before debug use
TrigpH equ 3 ; Trigger pin was High before debug use
;
page
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Initializing ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
org 0
goto Startp ; Go to start entry
org 4 ; This is Interrupt entry
retfie ;
;
Startp DEVset ; Define ports
clrf FSR0H ; Clear FSR0H forever
clrf FSR1H ; Clear FSR1H forever
clrf Flags ; Clear all bits of Flags
;
Milli D'50' ; Wait devices stabilized
call IniTMr ; Set-up TM1638 display
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Main program loop ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Mainp call RTCrdr ; Read clock
call Dsptime ; Display time
Secs 1 ; for 1 second
;
btfss PORTsw,swSet ; Set switch when time displayed ?
call RTCupdr
Secs 1 ; Time for another second
;
call DHTrd ; Read DHT11
call DspCT ; Display celsium degree
Secs 2 ; for 2 seconds
call DspHT ; Disuplay relative humidity
Secs 2 ; for 2 seconds
;
goto Mainp ; Contilue infinite loop
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; RTC updating routine ;
; Display value for current ModeN ;
; If swMode pushed, display next unit to update ;
; If swTime pushed, increase value and display it ;
; If swSet pushed, update RTC (RTCwtr) ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
RTCupdr btfss PORTsw,swSet ; swSet still on?
goto $-1 ; then wait for off
movlw Modeyr ; set initial mode year
movwf ModeN
;
RTCudm movf ModeN,W ; Large loop on ModeN
brw
goto Mdsecr ; case ModeN=0
goto Mdminr ; case ModeN=1
goto Mdhrr ; case ModeN=2
goto Mddowr ; case ModeN=3
goto Mddayr ; case ModeN=4
goto Mdmonr ; case ModeN=5
goto Mdyrr ; case ModeN=6
;
; Macro used within this section
Mdsetup macro T7c,Rmax,Rmin
movlw T7c
movwf T7Chr
movlw Rmax
movwf RvMax
movlw Rmin
movwf RvMin
goto Mdnext
endm
;
; set up environment for update and display
Mdsecr Mdsetup Ch7S,secMax,secMin
Mdminr Mdsetup Ch7m,minMax,minMin
Mdhrr Mdsetup Ch7h,hrMax,hrMin
Mddowr Mdsetup Ch7w,dowMax,dowMin
Mddayr Mdsetup Ch7d,dayMax,dayMin
Mdmonr Mdsetup Ch7M,monMax,monMin
Mdyrr Mdsetup Ch7Y,yrMax,yrMin
;
Mdnext call Rdspr ; Display X=nn
btfss PORTsw,swTime ; Is Time pushed ?
goto Rinc ; Yes, goto Rinc
btfss PORTsw,swMode ; Is Mode pushed ?
goto Rnxtm ; Yes, goto Rnxtm
btfss PORTsw,swSet ; Is Set pushed ?
goto Rwrite ; Yes, goto Rwrite
goto Mdnext ; If no button, small loop for button
;
; Time pushed here
Rinc call Rincr ; Increase value in that mode
Mil100 2 ; 0.2 sec for increasing value
goto Mdnext ; return to loop for button
;
; Mode pushed here
Rnxtm btfss PORTsw,swMode ; Mode button still pushed
goto $-1 ; then wait for release
CalEO ModeN,0,Msmax ; If current ModeN=0 goto Msmax
decf ModeN,F ; set next mode
Rnxtme goto RTCudm ; and return to large loop for mode
;
Msmax movlw Modeyr ; get maximum mode
movwf ModeN ; and set it
goto RTCudm ; and return to large loop for mode
;
Rwrite btfss PORTsw,swSet ; Set button still on?
goto $-1 ; then wait for release
call RTCwtr ; and write to RTC
;
return ; exit from RTC updating routine
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Display value pointed by ModeN ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Rdspr movf T7Chr,W
movwf Dig1000
movlw Ch7Eq
movwf Dig100
;
movlw BCDsec ; Point BCD area top
movwf FSR1L ; set it to FSR1L
movf ModeN,W ; Get Mode number
addwf FSR1L,F ; Point current BCD area
swapf INDF1,W ; get high nibble to low in W
call TMser ; clear high nibble & edit
movwf Dig10 ; set it to Dig10
movf INDF1,W ; get low nibble to low
call TMser ; clear high nibble to low
movwf Dig1 ; set it to Dig1
;
call TMdspr
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Increase value pointed by ModeN ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Rincr movlw BCDsec ; Point BCD area top
movwf FSR1L ; set it to pointer
movf ModeN,W ; get ModeN to add
addwf FSR1L,F ; Point current BCD area
;
CabSO INDF1,RvMax,Rigo ;If smaller than max, goto Rigo
movf RvMin,W ; Else, get minimum value
movwf INDF1 ; and set it to INDF1 (BCD area)
return
;
Rigo movf INDF1,W ; Get BCD value
andlw H'0F' ; clear left nibble
movwf Bytel ; and set to Bytel
swapf INDF1,W ; Get BCD nibbles swapped
andlw H'0F' ; clear left nibble
movwf Byteh ; and set to Byteh
;
incf Bytel,F ; Bytel+1
CalSO Bytel,D'10',Rie ; If Bytel≦9,goto Rie
movlw D'16' ; Else increase digit 10
addwf INDF1,F ;
movlw H'F0' ; and clear digit 1
andwf INDF1,F
return
Rie incf INDF1,F ; Increase BCD value
return ; and return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Displaying Time routine ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Dsptime movf BCDmin,W ; get minute dig 1
call TMser ; edit bit 0-3 value to 7 seg char
movwf Dig1 ; set it to Digit 1
;
swapf BCDmin,W ; get minutes dig 10
call TMser ; edit bit 0-3 value to 7 seg char
movwf Dig10 ; set it to Digit 10
;
movf BCDhr,W ; get hour dig 1
call TMser ; edit bit 0-3 value to 7 seg char
movwf Dig100 ; set it to Digit 100
bsf Dig100,7 ; set colon after Digit 100
;
swapf BCDhr,W ; get hour dig 10
call TMser ; edit bit 0-3 value to 7 seg char
movwf Dig1000 ; set it to Digit 1000
;
call TMdspr ; show them to TM1637
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; RTC reading routine ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
RTCrdr clrf RTCmem ; set RTC memory addr 0
I2Csnd DS3231,RTCmem,1 ; send it to DS3231
Milli 1 ; wait for readiness (unnecessary?)
I2Crcv DS3231,RTCdata,7 ; receive 7 byte data from DS3231
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; RTC writing routine ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
RTCwtr clrf RTCmem ; Set memory address zero
I2Csnd DS3231,RTCmem,8 ; Send data, with memory addr on top
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; DHT11 Reading routine ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
DHTrd movlw 5 ; Set # of DHT bytes 5
movwf Bytectr ; to Bytectr
;
movlw DHTrh ; Point top of DHT data input
movwf FSR0L ; Set it to INDF0
;
; Start signal
bcf PORTdht,DHT11 ; Set DHT-line L
;
Milli D'20' ; for 20mS
bsf PORTdht,DHT11 ; Set DHT-line H
Mic2 D'10' ; for 20 micro sec
;
;Header checking from DHT11
BANKSEL TRISdht ; Point tris bank
bsf TRISdht,DHT11 ; Set TRIS-dht input
clrf BSR ; Point bank 0
Mic ; wait 1 micro sec for ready
;
btfsc PORTdht,DHT11 ; Wait response 1/2 from DHT L
goto $-1 ; until L
Mic5 D'13' ; Wait 65 within 80 micS
;
btfss PORTdht,DHT11 ; Wait response 2/2 from DHT H
goto $-1 ; until H
Mic5 D'13' ; Wait 65 within 80 micS
;
btfsc PORTdht,DHT11 ; Wait Start (L 50 mic sec) from DHT
goto $-1
Mic5 D'6' ; When L, wait for 30 mic sec
;
; Read each byte from DHT11
DHbc movlw 8 ; Set # of bits = 8 in a byte of DHT
movwf Bitctr ; to Bitctr
;
DHbcl btfss PORTdht,DHT11 ; Wait Data signal H from DHT
goto $-1
Mic50 1 ; When H (1=70,0=27 micS), wait 50 micS
; Trigger ; *** for timing-validation use only ***
;
btfss PORTdht,DHT11 ; If still on then data is one, else zero
goto DHszero
;
DHsone bsf Sbyte,0 ; Set 1 to Sbyte bit 0
Mic5 D'4' ; Consume residual H 20 mic S of "1"
goto DHeck ; Goto Check end of one byte
;
DHszero bcf Sbyte,0 ; Set zero to Sbyte bit 0
DHeck decfsz Bitctr,F ; One byte (8 bits) end ?
goto DHnxtbi ; No, goto continue bit proc
;
DHbye movf Sbyte,W ; If one byte end, here
movwf INDF0 ; Set data to DHTdata entry
incf FSR0L,F ; Point next entry of DHTdata
;
decfsz Bytectr,F ; All bytes end?
goto DHbc ; If not end of bytes, next byte
goto DHcksr ; If end, checksum validation
;
DHnxtbi rlf Sbyte,F ; Bit continues. Shift left.
goto DHbcl ; and next bit checking
;
DHcksr equ $ ; Checksum validation, if needed
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; End of receive ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;Change data line mode to ooutput
; Wait the last space ending
Mic2 D'40' ; Residual 28 mic sec space + alpha
; ; + 50 mic sec until pull-down end
BANKSEL LATdht ; Data line high when output mode
bsf LATdht,DHT11 ; Lat-DHT11 high
BANKSEL TRISdht ; Select tris bank
bcf TRISdht,DHT11 ; Set DHT11 output mode
clrf BSR ; Select bank 0
;
Mic ; Wait one micro Sec
bsf PORTdht,DHT11 ; Signal high
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Display Celsius to TM1637 ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
DspCT clrf Dig1000 ; Clear Dig1000
movf DHTt,W ; Get DHTt
movwf Dig100 ; set it to Dig100
;
DspCTc CalSO Dig100,D'10',CTnext
incf Dig1000,F ; carry over to 1000
movlw D'10' ; and subtract 10
subwf Dig100,F ; from Dig100
goto DspCTc ; repeat check
;
CTnext CalEO Dig1000,0,CTnxtg ; IF top zero goto CTnxtg
movf Dig1000,W
call TMser ; Convert Dig1000 to 7 seg pattern
movwf Dig1000
;
CTnxtg movf Dig100,W
call TMser ; Convert Dig100 to 7seg pattern
movwf Dig100
;
movlw H'63' ; Char Degree
movwf Dig10
movlw H'39' ; Char C
movwf Dig1
;
call TMdspr
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Display Humidity to TM1637 ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
DspHT clrf Dig1000 ; Clear Dig1000
movf DHTrh,W ; Get DHTrh
movwf Dig100 ; set it to Dig100
;
DspHTc CalSO Dig100,D'10',HTnext
incf Dig1000,F ; carry over to 1000
movlw D'10' ; and subtract 10
subwf Dig100,F ; from Dig100
goto DspHTc ; repeat check
;
HTnext CalEO Dig1000,0,HTnxtg ; IF top zero goto HTnxtg
movf Dig1000,W
call TMser ; Convert Dig1000 to 7 seg pattern
movwf Dig1000
;
HTnxtg movf Dig100,W
call TMser ; Convert Dig100 to 7seg pattern
movwf Dig100
;
movlw H'63' ; Char % 1/2
movwf Dig10
movlw H'5C' ; Char % 2/2
movwf Dig1
;
call TMdspr
return
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; I2C Send byte-string ;
; when called, ;
; I2C device adr in I2Cadr byte ;
; Data length in DataLen ;
; Data Addr in FSR0L (INDF0) ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
I2Csndr movf I2Cadr,W
movwf Sbyte
; rlf Sbyte,F ; shift leftt (if adr for Arduino)
bcf Sbyte,0 ; indicate write
;
I2Cstat ; Start I2C
call Sendr
Sdata movf INDF0,W ; Get a sending character
movwf Sbyte ; Set it to Sbyte
call Sendr ; Send it to the device
;
incf FSR0L,F ; point next char
decfsz DataLen,F ; Have all chars sent ?
goto Sdata ; No, loop
;
; Stop signal and return
I2Cstop
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; I2C Receive byte-string ;
; when called, ;
; I2C device adr in I2Cadr byte ;
; Data length in DataLen ;
; Data Addr in FSR0L (INDF0) ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
I2Crcvr equ $
I2Cstat ; Start I2C
movf I2Cadr,W ; Get I2C dev addr
movwf Sbyte ; Set it into Sbyte
; rlf Sbyte,F ; Shift left (if adr for Arduino)
bsf Sbyte,0 ; indicate read
call Sendr ; Send slave addr to read
;
I2Crbyt equ $
BANKSEL TRISI2C ;
bsf TRISI2C,Dl ; Set Dline input mode
clrf BSR ; Point Bank 0
;
movlw 8 ; Bits in a reciving byte
movwf Bitctr ; into loop counter
I2Crblp Mic2p5 2*Clkt ; Timing before raising clock
bsf PORTI2C,Cl ; Set clock high
Mic2p5 Clkt ; Timing after raising clock
;
btfsc PORTI2C,Dl
goto Rbith
; goto Rbitl
;
Rbitl bcf Sbyte,0 ; Clear bit 0
goto Rbitnxt ; and goto next
;
Rbith bsf Sbyte,0 ; Set bit 0
Rbitnxt Mic2 Clkq ; Timing after checking
bcf PORTI2C,Cl ; Set clock low
; Mic2p5 Clkt ; Timing after clock falling
decfsz Bitctr,F ; Still bits?
goto Rbcont ; Yes, continue
goto Rbend ; No, end of one byte
;
Rbcont rlf Sbyte,F ; Shit left
goto I2Crblp ; and goto loop
;
Rbend movf Sbyte,W ; Get received byte
movwf INDF0 ; Set it to INDF0
incf FSR0L,F ; increase index
decfsz DataLen,F ; DataLen-1
goto Sackr ; Send Ack and continue
goto Snackr ; Send Nack and stop
;
;Set Dl output mode and send Ack to conitinue
Sackr equ $
BANKSEL LATI2C ; Data line high when output mode
bsf LATI2C,Dl ; Lat-Dl on
BANKSEL TRISI2C ;
bcf TRISI2C,Dl ; Set Dl output mode
clrf BSR ; Point Bank 0
;
bcf PORTI2C,Dl ; Send Ack
Mic2 Clkq ; Timing after clock falling
bsf PORTI2C,Cl ; Show Ack
Mic2p5 2*Clkt
bcf PORTI2C,Cl ; Set clock low
Mic2 Clkq
bsf PORTI2C,Dl ; Return Dline to high
goto I2Crbyt ; Next byte process
;
;Set Dl output mode and send Nack
Snackr equ $
BANKSEL LATI2C ; Data line high when output mode
bsf LATI2C,Dl ; Lat-Dl on
BANKSEL TRISI2C ;
bcf TRISI2C,Dl ; Set Dl output mode
clrf BSR ; Point Bank 0
;
bsf PORTI2C,Dl ; Send Nack
Mic2 Clkq ; Timing after clock falling
bsf PORTI2C,Cl ; Show Nack
Mic2p5 2*Clkt
bcf PORTI2C,Cl ; Set clock low
Mic2p5 Clkt
I2Cstop ; and stop I2C once
Mic5 D'6' ; for 30 micro sec
;
I2Cstat ; then start I2C again
movf I2Cadr,W ; Get I2C dev addr
movwf Sbyte ; Set it into Sbyte
; rlf Sbyte,F ; Shift left (if adr for Arduino)
bcf Sbyte,0 ; indicate write
call Sendr ; Send it
;
I2Cstop
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; I2C Start signal routine ;
; when dataline mode is output ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
I2Cstar bcf PORTI2C,Dl ; set SDA low
Mic2 Clkq
bcf PORTI2C,Cl ; set SCL low
Mic2p5 2*Clkt
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; I2C Stop signal routine ;
; when dataline mode is output ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
I2Cstpr bcf PORTI2C,Cl ; set SCL low
Mic2 Clkq
bcf PORTI2C,Dl ; set SDA low
Mic2p5 2*Clkt
bsf PORTI2C,Cl ; Clock line rasing
Mic2p5 Clkt
bsf PORTI2C,Dl ; Data line rasing
Mic2 Clkq
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; I2C One-byte sending routine ;
; with data in Sbyte ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Sendr movlw 8 ; Set bit count in a byte
movwf Bitctr ; into loop counter
;
Sloop btfsc Sbyte,7 ; Check top bit of Sbyte
goto Slpdh ;
bcf PORTI2C,Dl ; If bit low then Data L
goto Slpnxt
Slpdh bsf PORTI2C,Dl ; If bit high then Data H
;
Slpnxt Mic2 Clkq
bsf PORTI2C,Cl ; Show bit
Mic2p5 2*Clkt
bcf PORTI2C,Cl ;
Mic2 Clkq
;
rlf Sbyte,F ; Shift left
decfsz Bitctr,F ; All bits done?
goto Sloop ; No, loop within a byte
;
;Receive Ack
; set data line input mode
BANKSEL TRISI2C ;
bsf TRISI2C,Dl ; Set Dline input mode
clrf BSR ; Point Bank 0
;
Mic2 Clkq ; wait for Ack timing
bsf PORTI2C,Cl ; Clock H for Acq confirmation
Mic2p5 2*Clkt ;
bcf PORTI2C,Cl ; Cl L for Dl release by slave
Mic2p5 2*Clkt
;
; Set Data line output
BANKSEL LATI2C ; Data line high when output mode
bsf LATI2C,Dl ; Lat-Dl on
BANKSEL TRISI2C ;
bcf TRISI2C,Dl ; Set Dl output mode
clrf BSR ; Point Bank 0
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; TM1637 support routines ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; TM1637 display brightness setting ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
IniTMr equ $
; TM brightness initial setting ;
; H'88'+ duty ratio:
; H'00'=1/16, H'01'=2/16, H'02'=4/16, H'03'=10/16
; H'04'=11/16, H'05'=12/16, H'06'=13/16, H'07'=14/16
movlw H'88'+H'02' ; Initial brightness value
movwf Sbyte ; Set to Sbyte
TMstart
TMsendB Sbyte
TMstop
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; TM 1637 Char to 7 segment editing routine ;
; replaceubg Char in W with 7 seg in W ;
; 7 seg format is B'xgfe-dcba' ;
; if colon required,IOR H'80' to Dig100 ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
TMser andlw H'0F' ; Prevent wild branch
brw
Case0 retlw H'3F'
Case1 retlw H'06'
Case2 retlw H'5B'
Case3 retlw H'4F'
Case4 retlw H'66'
Case5 retlw H'6D'
Case6 retlw H'7D'
Case7 retlw H'07'
Case8 retlw H'7F'
Case9 retlw H'6F'
CaseA retlw H'77' ; A
CaseB retlw H'7C' ; b
CaseC retlw H'39' ; C
CaseD retlw H'5E' ; d
CaseE retlw H'79' ; E
CaseF retlw H'71' ; F
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; TM1637 4digits displaying routine ;
; using Dig1000 to Dig1 ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
TMdspr movlw Dig1000 ; Point Byte0 address
movwf FSR0L ; set it to use INDF0
movlw 4 ; Set four digits
movwf Bytectr ; to Byte counter
;
TMstart
TMsendL H'40' ;
TMstop ;
;
TMstart
TMsendL H'C0' ; Set addr zero of TM
;
TMdspl movf INDF0,W ; Get byte contents
movwf Sbyte ; Set them to Sbyte
TMsendB Sbyte ;
incf FSR0L,F ; point next byte
decfsz Bytectr,F ; Check if all done
goto TMdspl ; No. loop
;
TMstop ; When all sent, Stop
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; TM1637 Start sending routine ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
TMstrtr nop
BANKSEL TRIStm
bsf LATtm,Dio ; Dio high beforhand
bcf TRIStm,Dio ; Set Dio output
clrf BSR ; return to Bank0
;
bsf PORTtm,Dio ; Dio high
Mic2 Clkq
bsf PORTtm,Clk ; Clk high
Mic2 Clkq
bcf PORTtm,Dio ; Dio low
Mic2 Clkq
bcf PORTtm,Clk ; Clk low
Mic2 Clkq
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; TM1637 Stop sending routine ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
TMstopr nop
BANKSEL TRIStm
bcf LATtm,Dio ; Dio low beforehand
bcf TRIStm,Dio ; Set Dio output
clrf BSR ; Return to Bank0
;
Mic2 Clkq
bsf PORTtm,Clk ; Clk high
Mic2 Clkq
bsf PORTtm,Dio ; Data high
Mic2p5 D'10'
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; TM1637 Byte sending routine ;
; called by TMsendB with Sbyte or ;
; TMsendL with value in W reg ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
TMsndLr movwf Sbyte ; Set sending byte
;
TMsndBr movlw 8 ; Set bit count
movwf Bitctr ; into loop counter
;
Tloop btfsc Sbyte,0 ; Check LSb for little-endian-
goto Tlpdh ;
bcf PORTtm,Dio ; If bit low then Data L
goto Tlpnxt
;
Tlpdh bsf PORTtm,Dio ; If bit high then Data H
Tlpnxt Mic2 Clkq;
bsf PORTtm,Clk ; Clock high
Mic2p5 2*Clkt ; (5 micro sec if standard)
bcf PORTtm,Clk ; Clock low
Mic2 Clkq
rrf Sbyte,F ; Shift right for little-endian
decfsz Bitctr,F
goto Tloop
;
; Receiving Ack ;
BANKSEL TRIStm
bsf TRIStm,Dio ; Set Dio input mode
clrf BSR ; return to Bank0
Mic2p5 Clkt ; Wait for Ack=low
bsf PORTtm,Clk ; Clk high for Ack confirmation
Mic2p5 2*Clkt ; (5 micro sec if standard)
bcf PORTtm,Clk ; Clk L for Data release to H by Slave
Mic2p5 Clkt ; Wait for Dio set H
;
BANKSEL TRIStm
bsf LATtm,Dio ; Dio high beforhand
bcf TRIStm,Dio ; Set Dio output
clrf BSR ; return to Bank0
Mic2p5 5 ; Enough time for TM1637 after Ack
return ;
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Timing subrooutines for general purposes ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Make 2.0 micro S x n (Mic2) ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Mic2r movwf Mic25c ; + Wset + call = 1 micro sec
;
Mic2l decfsz Mic25c,F ; If exhausted, 1 micro S hereafter
goto Mic2li ; else go out (2nd time 1.75 mic sec)
return
;
Mic2li goto $+1 ; (2nd time 2.25 mic sec)
nop ; (2nd time 2.5 mic sec)
goto Mic2l ; go back (2nd time 3 micro sec)
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Make 2.5 micro S x n (Mic2p5) ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Mic25r movwf Mic25c ; + Wset + call = 1 micro sec
nop ; 1.25 micro sec
;
Mic25l nop ; 1.5 micro sec (2nd time 4 mic sec)
decfsz Mic25c,F ; If exhausted, 1 micro S hereafter
goto Mic25li ; else go out (2nd time 2.25 mic sec)
return
;
Mic25li Mic ; (2nd time 3.25 mic sec)
goto Mic25l ; go back (2nd time 3.75 micro sec)
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 50 Microseconds x n Mic50 ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
Mic50r movwf Mic50c ; set how many 50 microsec (1 micro sec to here)
nop ; 1.25 micro sec up to here
;
Mic50l Mic2p5 D'19' ; + 47.5 = 48.75 mic sec (2nd time 98.75 mic sec)
nop ; + 0.25 = 49 micro sec (2nd time 99 mic sec)
;
decfsz Mic50c,F ; If exhausted then 1 mic S hereafter
goto Mic50li ; else go out (2nd time 49.75 mic sec)
return
;
;
Mic50li Mic ; (2nd time 50.75 mic sec)
goto Mic50l ; go back (2nd time 51.25 mic sec)
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Milliseconds x n (Milli) ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
Millir movwf Millic ; set how many 1 mil sec (1 mic S up to here)
nop ; 1.25 micro sec
;
Millil Mic50 D'19' ; + 50 mic x 19 = 951.25 mic S (2nd, 1951.25)
Mic2p5 D'19' ; + 47.5 mic = 998.75 micro S (2nd, 1998.75)
nop ; +0.25 mic = 999 micro sec (2nd, 1999)
;
decfsz Millic,F ; If exhausted then 1 micro sec hereafter
goto Millili ; else go out (2nd, 999.75 mic S)
return
;
Millili Mic ; (2nd time 1000.75 mic S)
goto Millil ; go back (2nd time 1001.25 mic S)
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 100 Milliseconds x n (Mil100);
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Mil100r movwf Mil100c ;set how many 100 ms(1 micr sec up to here)
nop ; 1.25 micro sec
;
Milhl Milli D'99' ;+1ms x 99 = 99001.25 micS (2nd,199001.25mic)
Mic50 D'19' ; + 950 mic = 99951.25 micS(2nd.199951.25mic)
Mic2p5 D'19' ; + 47.5 mic = 99998.75micS(2nd,199998.75mic)
nop ; + 0.25 mic = 99999 mic S (2nd,199999 micS)
;
decfsz Mil100c,F ; If exhausted then 1 micro sec hereafter
goto Milhli ; else go out (2nd time, 99999.75 mic S)
return
;
Milhli Mic ; (2nd time, 100000.75 mic S)
goto Milhl ; (2nd time, 100001.25 mic S)
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Seconds x n (Secs) ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
Secsr movwf Secsc ; set how many sec ( 1 mic sec up to here)
nop ; 1.25 micro sec
;
Secsl Mil100 D'9' ;
Milli D'99' ; + 999 milli sec = 999001.25 micro sec
;
Mic50 D'19' ; + 950 mic = 999951.25 micro sec
Mic2p5 D'19' ; + 47.5 mic = 999998.75 micro sec
nop ; + 0.25 mic = 999999 micro sec
;
decfsz Secsc,F ; If exhausted then 1 micro sec hereafter
goto Secsli ; else, go out
return
;
Secsli Mic
goto Secsl ; (Second time, Sec + 1.25 micro sec)
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Minutes x n (Mins) ;
; Overhead ignored, that is only ;
; 751.25 Mic S even when 100 Min ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Minsr movwf Minsc ;set how many minutes from parameter
;
Minsl Secs D'60' ; 1 Seconds x 60
decfsz Minsc,F
goto Minsl
return
;
space
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; User debug subroutine ;
; Show bit 7 to 0 ;
; of specified byte ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Udbgr clrf BSR ; Set Bank=0
movwf DmpA ; move data to Dmpa
;
btfss PORTdbg,LED ; Check if LED=on (on=High)
goto UdbLoff ; if LED=off(Low), skip saving process
bsf Flags,LEDpH ; Save LEDon status
LEDoff ; and off LED
Mil100 D'10' ; wait for a second in case LED has been on
;
UdbLoff movlw Dmp8V ; set counter 8
movwf Dmp8C ; to Dmp8C
;
Udblp Ublink Debugb ; Blink for Debug = 8 times
btfsc DmpA,7 ; check top bit 7
goto UdbOn ; if on then to UdbOn
goto UdbOff ; if off then to UdbOff
;
UdbOn LEDon
Mil100 D'30' ;
goto Udbeck
;
UdbOff LEDoff
Mil100 D'30' ;
; goto Udbeck
;
Udbeck decfsz Dmp8C,F
goto Udbnext
goto Udbend
;
Udbnext rlf DmpA,F
goto Udblp
;
Udbend Ublink Debugb ; end blinking and
Mil100 D'100' ; blank for 10 seconds to write down
;
btfss Flags,LEDpH ; Check if LED was on
goto Udbret ; no, goto return
LEDon ; if it was on, then on again
bcf Flags,LEDpH ; Clear LED save flag
;
Udbret return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Blinking to show debug or abend ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Ublinkr movwf BlinkC
Ublinkl LEDon ; LED on
Milli D'30' ; for 30ms
LEDoff ; LED off
Milli D'200' ; for 200ms
;
decfsz BlinkC,F
goto Ublinkl
return
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Abend routine ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Uabendr clrf BSR
movwf Abendn ; Set Uabend number
;
Ublink Abendb ; Blink 25 times
Udebug Abendn ; Show Abend number
goto $
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; End of program ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
end
ピンがこれでいっぱいかといえばそんなことはありません。無理しない手がまだあります。
入出力をもっと追加するには例えば次のようにします。
もともとこの8ピンPICの仕様上RA3が単にデジタル入力しかできないので、これをModeボタンとして使わずSetボタンとして使うように入れ替えます。Setボタンが押された時（時刻設定モード）以外はTimeボタンとModeボタンは空いています！から（今回すでにTimeボタンをデバッグ用Trigger出力またはLED点灯に使えるようにプログラムして使っています）、自由に使えます。
同様に、時刻設定モード以外の通常時にいつも空いているModeボタンが自由に使えるようになるわけです。例えば通常時はアナログ入力ピンとして使えば、アナログ入力デバイスも読み込めます。照度計、ホール素子、マイク、風速計など、それこそ色々ありますね。もちろん出力ピンにして動くものなど繋いでもよいですが。
つまり時刻設定モードのときだけ入力ボタンにすればよいのであって、それ以外は空いているのと同じこと。
また、TM1637は、クロック信号（CLK)を与えない間は表示を保持します。ですので、表示データ送出時以外は単に2秒待たせるのではなく、データ信号（DIO)ピンが別用途に使えます。TM1637側でのプルアップを考慮した上で、ブザーをならすとかトランジスタ経由で何かを動かすとか、逆にデジタル入力ピン（プルアップ）として使っても問題ないはずです。
つまり、「もったいないばあさん」に言わせれば、まだ2つのピンが使える状態です。
これに充てる時間が次にできたときには、プログラムの解説よりも先にどれかを足してみようかとも。。そうすればインターフェイス満載の参照用プログラムになるかも。。え？部品取りのジャンク？・・^^;
では今回はこの辺で。
©2019 Akira Tominaga, All rights reserved.
